nixos/modules/crans/networking.nix

{ lib, config, hosts, ... }:

let
  cfg = config.crans;
  cfg-net = cfg.networking;

  inherit (lib)
    mkEnableOption
    mkIf
    mkOption
    types
    mod
    ;

  idString = toString cfg.id;
  hostId = lib.mod cfg.id 100;
  hostIdString = lib.fixedWidthString 2 "0" (toString hostId);
  isVm = cfg.id >= 100;
  isVmString = toString isVm;
  get_mac = id: vlan_num:
    "02:00:00:0${toString (id >= 100)}:${toString (mod id 100)}:${lib.fixedWidthString 2 "0" (toString vlan_num)}";
in
{
  options.crans.networking = {
    enable = mkEnableOption "Configuration réseaux commune à toutes les machines du Crans.";

    adm = {
      enable = mkEnableOption "Configuration du VLAN adm.";

      interface = mkOption {
        type = types.str;
        default = "ens18";
        example = "ens20";
        description = "Nom de l'interface réseau sur laquelle est située le VLAN adm.";
      };

      ipv4 = mkOption {
        type = types.str;
        example = "176.16.10.102";
        default = "172.16.10.${idString}";
        description = "Adresse IPv4 de la machine sur le VLAN adm";
      };

      ipv6 = mkOption {
        type = types.str;
        example = "fd00::10:0:ff:fe01:0210";
        default = "fd00::10:0:ff:fe0${isVmString}:${hostIdString}10";
        description = "Adresse IPv6 de la machine sur le VLAN adm";
      };
      
    };

    srv = {
      enable = mkEnableOption "Configuration du VLAN srv.";

      interface = mkOption {
        type = types.str;
        default = "ens19";
        example = "ens20";
        description = "Nom de l'interface réseau sur laquelle est située le VLAN srv.";
      };

      ipv4 = mkOption {
        type = types.str;
        example = "185.230.79.1";
        description = "Adresse IPv4 de la machine.";
      };
      
      ipv6 = mkOption {
        type = types.str;
        example = "2a0c:700:2::ff:fe01:0202";
        default = "2a0c:700:2::ff:fe0${isVmString}:${hostIdString}02";
        description = "Adresse IPv6 de la machine sur le VLAN srv.";
      };
    };

    srvNat = {
      enable = mkEnableOption "Configuration du VLAN srv-nat.";

      interface = mkOption {
        type = types.str;
        default = "ens19";
        example = "ens20";
        description = "Nom de l'interface réseau sur laquelle est située le VLAN srv-nat.";
      };

      ipv4 = mkOption {
        type = types.str;
        example = "176.16.3.102";
        default = "172.16.3.${idString}";
        description = "Adresse IPv4 de la machine sur le VLAN srv-nat.";
      };

      ipv6 = mkOption {
        type = types.str;
        example = "2a0c:700:3::ff:fe01:0203";
        default = "2a0c:700:3::ff:fe0${isVmString}:${hostIdString}03";
        description = "Adresse IPv6 de la machine sur le VLAN srv-nat.";
      };
    };

    san = {
      enable = mkEnableOption "Configuration du VLAN san.";

      interface = mkOption {
        type = types.str;
        example = "ens19";
        description = "Nom de l'interface réseau sur laquelle est située le VLAN san.";
      };
      
      ipv4 = mkOption {
        type = types.str;
        example = "176.16.4.102";
        default = "172.16.4.${idString}";
        description = "Adresse IPv4 de la machine sur le VLAN srv-nat.";
      };

      ipv6 = mkOption {
        type = types.str;
        example = "fd00::4:0:ff:fe01:0204";
        default = "fd00::4:0:ff:fe0${isVmString}:${hostIdString}04";
        description = "Adresse IPv6 de la machine sur le VLAN san.";
      };
    };
  };

  config = mkIf cfg-net.enable {
    networking = {
      hostName = cfg.name;
      useDHCP = false;
      firewall.enable = lib.mkDefault false;
      nameservers = [ "172.16.10.128" ];

      # La configuration des interfaces se fait de la manière suivante :
      # elle est écrite de manière générique pour toutes les machines, puis
      # on filtre pour ne garder que les interfaces activées. nix fait de
      # l'évaluation paresseuse donc ça fonctionne bien !
      interfaces =
        # On change le nom des interfaces de "adm", "srv", ... pour leur vrai
        # nom (on ne le met pas directement pour faire fonctionner le filter
        # plus bas).
        lib.attrsets.mapAttrs'
          (interface: conf: {
            name = cfg-net."${interface}".interface;
            value = conf;
          })
          (
            # On filtre sur les interfaces activées
            lib.attrsets.filterAttrs (interface: _: cfg-net."${interface}".enable) {
              # Configuration du VLAN adm
              adm = {
                ipv4.addresses = [
                  {
                    address = cfg-net.adm.ipv4;
                    prefixLength = 24;
                  }
                ];

                ipv6.addresses = [
                  {
                    address = cfg-net.adm.ipv6;
                    prefixLength = 64;
                  }
                ];
              };

              # Configuration du VLAN srv
              srv = {
                ipv4 = {
                  addresses = [
                    {
                      address = cfg-net.srv.ipv4;
                      prefixLength = 26;
                    }
                  ];
                  routes = [
                    {
                      address = "0.0.0.0";
                      via = "185.230.79.62";
                      prefixLength = 0;
                    }
                  ];
                };
                ipv6 = {
                  addresses = [
                    {
                      address = cfg-net.srv.ipv6;
                      prefixLength = 64;
                    }
                  ];
                  routes = [
                    {
                      address = "::";
                      via = "2a0c:700:2::ff:fe00:9902";
                      prefixLength = 0;
                    }
                  ];
                };
              };

              # Configuration du VLAN srv-nat
              srvNat = {
                ipv4 = {
                  addresses = [
                    {
                      address = cfg-net.srvNat.ipv4;
                      prefixLength = 24;
                    }
                  ];
                  routes = [
                    {
                      address = "0.0.0.0";
                      via = "172.16.3.99";
                      prefixLength = 0;
                    }
                  ];
                };

                ipv6 = {
                  addresses = [
                    {
                      address = cfg-net.srvNat.ipv6;
                      prefixLength = 64;
                    }
                  ];
                  routes = [
                    {
                      address = "::";
                      via = "2a0c:700:3::ff:fe00:9903";
                      prefixLength = 0;
                    }
                  ];
                };
              };

              # Configuration du VLAN san
              san = {
                ipv4.addresses = [
                  {
                    address = cfg-net.san.ipv4;
                    prefixLength = 24;
                  }
                ];

                ipv6.addresses = [
                  {
                    address = cfg-net.san.ipv6;
                    prefixLength = 64;
                  }
                ];
              };
            }
          );
    };
  };
}