nixos/flake.nix

{
  description = "Configuration NixOS du Crans";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-26.05";
    flake-parts.url = "github:hercules-ci/flake-parts";

    # Formatter
    treefmt-nix = {
      url = "github:numtide/treefmt-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    # Secret management
    agenix = {
      url = "github:ryantm/agenix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
  };

  outputs =
    inputs@{
      self,
      nixpkgs,
      flake-parts,
      agenix,
      ...
    }:
    let
      lib = nixpkgs.lib.extend (
        final: prev:
        import ./lib {
          inherit inputs;
          lib = final;
        }
      );
    in
    flake-parts.lib.mkFlake { inherit inputs; } {
      imports = [ inputs.treefmt-nix.flakeModule ];

      systems = [ "x86_64-linux" ];

      flake = with lib.crans.info; {
        nixosConfigurations =
          let
            baseModules = [
              ./modules
              agenix.nixosModules.default
            ];

            attrs_vm_info = listInfoToAttrs (get_info ./hosts/vm) { isVm = true; };
            attrs_physique_info = listInfoToAttrs (get_info ./hosts/physiques) { isVm = false; };
            attrs_all_info = attrs_physique_info // attrs_vm_info;
          in
          (attrsToNixosSystem ./hosts/vm attrs_all_info attrs_vm_info baseModules)
          // (attrsToNixosSystem ./hosts/physiques attrs_all_info attrs_physique_info baseModules)
          // {
            cransIso = lib.nixosSystem {
              system = "x86_64-linux";
              specialArgs = inputs;
              modules = [
                ./hosts/iso
                ./modules/crans/locale.nix
              ];
            };
          };
      };

      perSystem =
        { config, pkgs, ... }:
        {
          devShells = {
            default = pkgs.callPackage ./devshells/default.nix { inherit (inputs) agenix; };
          };
        };
    };
}