nixos/modules/crans/networking.nix

127 lines
3.1 KiB
Nix
Raw Blame History

This file contains invisible Unicode characters!

This file contains invisible Unicode characters that may be processed differently from what appears below. If your use case is intentional and legitimate, you can safely ignore this warning. Use the Escape button to reveal hidden characters.

This file contains ambiguous Unicode characters that may be confused with others in your current locale. If your use case is intentional and legitimate, you can safely ignore this warning. Use the Escape button to highlight these characters.

{
lib,
config,
hosts,
...
}:
let
cfg = config.crans;
cfg-net = cfg.networking;
inherit (lib)
mkEnableOption
mkIf
mkOption
mkDefault
types
mod
mapAttrs
mapAttrs'
filterAttrs
mergeAttrsList
optional
fixedWidthString
nameValuePair
;
in
{
options.crans.networking = {
enable = mkEnableOption "Configuration réseaux commune à toutes les machines du Crans.";
}
// mapAttrs (
vlan: conf:
let
vlanId = mod conf.id 100;
in
mergeAttrsList (
[
{
enable = mkEnableOption "Activation du réseau ${vlan}";
interface = mkOption {
type = types.str;
description = "Interface pour le réseau ${vlan}";
default = conf.interface;
};
defaultRoutes = mkOption {
type = types.bool;
default = true;
description = "Configuration par défaut des routes de ${vlan}";
};
}
]
++ optional ((conf.ipv4 or true) != null) {
ipv4 = mkOption {
type = types.str;
description = "Adresse IPv4 de la machine sur le réseau ${vlan}";
default = "172.16.${toString vlanId}.${toString cfg.id}";
};
}
++ optional ((conf.ipv6 or true) != null) (
let
# XXX: Utilisation du masque pour le déterminer à la place ?
prefix =
if lib.hasPrefix "2a0c:700" conf.ipv6.address then
"2a0c:700"
else if lib.hasPrefix "fd00:0:0" conf.ipv6.address then
"fd00:0:0"
else
(builtins.warn "Le prefixe de ${conf.ipv6.address} n’est pas reconnu");
in
{
ipv6 = mkOption {
type = types.str;
description = "Adresse IPv6 de la machine sur le réseau ${vlan}";
default = "${prefix}:${toString vlanId}::ff:fe0${toString (cfg.id / 100)}:${toString (mod cfg.id 100)}${
fixedWidthString 2 "0" (toString vlanId)
}";
};
}
)
)
) cfg.vlans;
config = mkIf cfg-net.enable {
networking = {
hostName = cfg.name;
useDHCP = false;
firewall.enable = mkDefault false;
nameservers = [
# Romanesco via adm
"172.16.10.128"
"fd00::10:0:ff:fe01:2810"
];
interfaces = mapAttrs' (
vlan: vconf:
let
conf = cfg-net.${vlan};
in
nameValuePair conf.interface (
# On itère ipv4 / ipv6
builtins.mapAttrs
(
ipvx: _:
mkIf (vconf.${ipvx} != null) {
addresses = [
{
address = conf.${ipvx};
prefixLength = vconf.${ipvx}.prefixLength;
}
];
routes = mkIf conf.defaultRoutes vconf.${ipvx}.routes;
}
)
{
"ipv4" = null;
"ipv6" = null;
}
)
) (filterAttrs (n: _: cfg-net.${n}.enable) cfg.vlans); # On filtre les interfaces désactivées.
};
};
}